home *** CD-ROM | disk | FTP | other *** search
/ Almathera Ten Pack 3: CDPD 3 / Almathera Ten on Ten - Disc 3: CDPD3.iso / scope / 201-220 / scopedisk211 / climax / purify.a < prev    next >
Encoding:
Text File  |  1995-03-20  |  9.1 KB  |  252 lines
  1. * This here is startup code for Amiga Aztec C programs, to make them pure.
  2. * Assemble it with the command "as purify.a" and link the resulting purify.o
  3. * file with your C program, in some manner like "ln yourprogram.o purify.o -lc",
  4. * and your program can then be marked as pure, and made resident, IF it meets
  5. * certain conditions:
  6. * 
  7. * 1) You must not use the large data model for accessing your global varialbes.
  8. * 
  9. * 2) You MUST NOT call the geta4() function from within any part of your program
  10. * that is run outside of your main process.  Subtasks, interrupt handlers, and
  11. * wedges installed with SetFunction may not use geta4, and thus may not access
  12. * your global variables by any direct method.
  13. * 
  14. * 3) You must not initialize global variables using the addresses of other
  15. * global variables.  For example, the following is not correct:
  16. * 
  17. *     char foo[100], bar[100];
  18. *     char *foobar[2] = { foo, bar };        /* WRONG */
  19. * 
  20. * If you do this, then any references to foobar[0] will end up accessing
  21. * DIFFERENT MEMORY than accessing foo directly will.  Instead, you have to do
  22. * such initialization in the code, with statements like "foobar[0] = foo;
  23. * foobar[1] = bar;".
  24. *
  25. * 4) You must not use detach.o; this applies to ALL pure programs, not just
  26. * those that use this startup code.
  27. * 
  28. * 5) Do not use this when making a shared library or device driver.  ("Duh...")
  29. * 
  30. * This was originally based on resident.asm by Olaf Barthel, which is available
  31. * on fish disk 396, but does not presently contain any of his code.  Barthel's
  32. * version had serious errors in it, and will not work in many cases.  It was
  33. * also a lot less efficient than the method I use.
  34. *
  35. * With the Aztec assembler, do not use the -N flag (one pass), because there's
  36. * a bug, at least in 5.2a and older, that makes the ENTRY directive not work
  37. * with that option.  It will need a few changes in syntax to work with other
  38. * assemblers.  It might be possible to make versions for other C compilers, so
  39. * I've labeled everything which I know to be Aztec specific with a comment
  40. * containing the word "Aztec".
  41. *
  42. * The one possibly uncool bit of programming used here is that I used
  43. * SysBase->ThisTask instead of FindTask(0), in several places.  If they ever
  44. * make an Amiga that runs tasks on several CPUs at once, that might break.
  45. * 
  46. * This is by Paul Kienitz, 1 December 1991, placed in the public domain.
  47.  
  48.  
  49. ; We avoid pulling in include files with a few definitions here:
  50.  
  51. MEMB_FAST    equ    2        ; exec/memory.i
  52. MEMB_CLEAR    equ    16        ; exec/memory.i
  53. ThisTask    equ    276        ; exec/execbase.i
  54. AttnFlags    equ    296        ; exec/execbase.i
  55. AFB_68881    equ    4        ; exec/execbase.i
  56. AG_OpenLib    equ    $30000        ; exec/alerts.i
  57. AO_DOSLib    equ    $8007        ; exec/alerts.i
  58. pr_ReturnAddr    equ    176        ; libraries/dosextens.i
  59. pr_CLI        equ    172        ; libraries/dosextens.i
  60. pr_MsgPort    equ    92        ; libraries/dosextens.i
  61.  
  62. _LVOTypeOfMem        equ    -534
  63. _LVOAllocMem        equ    -198
  64. _LVOOldOpenLibrary    equ    -408
  65. _LVOAlert        equ    -108
  66. _LVOSupervisor        equ    -30
  67. _LVOFreeMem        equ    -210
  68. _LVOCloseLibrary    equ    -414
  69. _LVOWaitPort        equ    -384
  70. _LVOGetMsg        equ    -372
  71. _LVOReplyMsg        equ    -378
  72. _LVOForbid        equ    -132
  73.  
  74.  
  75. lcall        macro
  76.         jsr    _LVO\1(a6)
  77.         endm
  78.  
  79. AbsExecBase    equ    (4).w
  80.  
  81.         xdef    .begin,_geta4
  82.         xref    __main,_SysBase,_DOSBase
  83.         xref    __savsp                    ; Aztec
  84.         xdef    entry,cleanup        ; for debugging
  85.  
  86. ; the use of the label ".begin" for the entry point is an Aztec-ism
  87.         entry    .begin
  88.  
  89. .begin:
  90. entry:
  91.         far    data                    ; Aztec
  92.         lea    __H1_org+32766,a4    ; to access original globals
  93.  
  94.         lea    __H1_end,a1        ; Aztec; end of initialized data
  95.         lea    __H2_org,a2        ; Aztec; start of BSS
  96.         near    data                    ; Aztec
  97.  
  98.         cmp.l    a1,a2            ; the same address?
  99.         bne    bomb            ; if not, refuse to run
  100.  
  101.         move.l    a0,d6            ; save command arg-line pointer
  102.         move.l    d0,d5            ; save command arg length
  103.  
  104.         lea    __H1_org,a1        ; Aztec; start of data hunk
  105.         move.l    AbsExecBase,a6
  106.         lcall    TypeOfMem        ; what kind of ram is it in?
  107.         bclr.l    #MEMB_FAST,d0        ; do NOT force fast ram!
  108.         bset.l    #MEMB_CLEAR,d0        ; do force cleared memory
  109.  
  110.         move.l    d0,d1            ; memory type requirements
  111.         move.l    #(__H2_end-__H1_org),d0    ; Aztec; size of all globals
  112.         lcall    AllocMem        ; space for a complete copy
  113.         tst.l    d0
  114.         beq    bomb            ; if it failed, don't run
  115.         move.l    d0,a2
  116.  
  117.         lea    __H1_org,a0        ; Aztec; address of old globals
  118.         move.l    a2,a1            ; address of new globals
  119.         move.l    #((__H1_end-__H1_org)/4)-1,d0    ; Aztec; size to copy
  120. copyit:        move.l    (a0)+,(a1)+        ; copy all initialized data
  121.         dbra    d0,copyit
  122.  
  123. * Here's where we get tricky.  We need to put the address of our dublicated
  124. * global variable space someplace where it can be found by geta4(), and we need
  125. * to make sure that we free the copied globals no matter how the program exits.
  126. * What we do is save the pointer on the stack, and then make it appear that the
  127. * final exit address that the program must return to is the address of our
  128. * cleanup routine.  To do this, after pushing the pointer to the copied globals,
  129. * we push the size of the remaining available stack (12 bytes less than the
  130. * original size) and then the address of the cleanup code.  We set the variable
  131. * __savsp to point to that cleanup code address, so that the Aztec exit()
  132. * function will return to that point.  We set the pr_ReturnAddr field of our
  133. * struct Process to point one longword above that, to make the dos.library
  134. * Exit() function return to the cleanup code.  This is also used by geta4() to
  135. * locate the saved pointer to the copied globals.
  136.  
  137.         move.l    a2,-(sp)        ; where geta4() can find it
  138.         move.l    8(sp),a0        ; original size of the stack
  139.         sub.w    #12,a0            ; minus space we're using
  140.         move.l    a0,-(sp)        ; make stack look smaller
  141.         move.l    ThisTask(a6),a0        ; equivalent to FindTask(0)
  142.         move.l    sp,pr_ReturnAddr(a0)    ; for geta4() and dos Exit()
  143.         pea    cleanup            ; so everybody goes there
  144.         move.l    sp,__savsp        ; Aztec; exit() and stack check
  145.  
  146. * The stack now looks like this:
  147. *
  148. *     Stack size in bytes        <-  old pr_ReturnAddr pointed here
  149. *     Return address for final exit    <-  __savsp would have pointed here
  150. *     Pointer to globals for geta4    <-  also used by cleanup
  151. *     New stack size, minus twelve    <-  new pr_ReturnAddr points here
  152. *     Fake return address: cleanup    <-  __savsp will point here
  153. *
  154. * Once __main is called, there will also be these:
  155. *
  156. *     Command line arg address    <-  argument to __main
  157. *     Command line arg length        <-  argument to __main ...SP is now here
  158. *     Return address to this module    <-  falls through to cleanup
  159.  
  160.         bsr    _geta4            ; use new globals
  161.         move.l    a6,_SysBase        ; set up base for C program
  162.         lea    dosname,a1
  163.         lcall    OldOpenLibrary        ; open dos.library
  164.         move.l    d0,_DOSBase        ; set up another base
  165.         bne    dosokay
  166.         move.l    #AG_OpenLib!AO_DOSLib,d7    ; recoverable - no dos
  167.         lea    ThisTask(a6),a5        ; make it show our task adr
  168.         lcall    Alert            ; frighten the user
  169.         bra    bomb            ; and die
  170.  
  171. dosokay:    btst.b    #AFB_68881,AttnFlags+1(a6)    ; is there an FPU?
  172.         beq    nofpu
  173.         lea    resetfpu,a5
  174.         lcall    Supervisor        ; reset it in supervisor mode
  175.  
  176. nofpu:        movem.l    d5/d6,-(sp)        ; pass arguments to _main()
  177.         jsr    __main            ; RUN THE PROGRAM!
  178.         add.w    #12,sp            ; pop extra longword to fake rts
  179.  
  180. cleanup:    move.l    d0,d7            ; set aside the return value
  181.         bsr    _geta4            ; so we can check DOSBase
  182.         move.l    4(sp),a1        ; address of copied globals
  183.         move.l    #(__H2_end-__H1_org),d0    ; size of copied globals
  184.         move.l    AbsExecBase,a6
  185.         lcall    FreeMem            ; get rid of the copy
  186.         addq    #8,sp            ; restore primordial stack
  187.         move.l    ThisTask(a6),a1
  188.         lea    4(sp),a0        ; just to be paranoid...
  189.         move.l    a0,pr_ReturnAddr(a1)    ; restore old pr_ReturnAddr
  190.  
  191.         move.l    _DOSBase,a1
  192.         move.l    a1,d0            ; fake tst.l a1
  193.         beq    dosneveropen        ; was there ever a DOSBase?
  194.         lcall    CloseLibrary        ; if yes, close it
  195.  
  196. dosneveropen:    move.l    d7,d0            ; restore the return value
  197.         rts                ; goodbye cruel world
  198.  
  199.  
  200. bomb:        move.l    AbsExecBase,a6        ; come here if we can't run
  201.         move.l    ThisTask(a6),a0
  202.         tst.l    pr_CLI(a0)        ; are we a Workbench process?
  203.         bne    noworkbench        ; if yes, then we need to
  204.                         ;   reply the startup message:
  205.         lea    pr_MsgPort(a0),a0
  206.         move.l    a0,a3            ; remember our msgport address
  207.         lcall    WaitPort        ; here come de message
  208.         move.l    a3,a0
  209.         lcall    GetMsg            ; got it
  210.         move.l    d0,d3            ; yes, remember it
  211.         lcall    Forbid            ; standard shutdown procedure
  212.         move.l    a3,a1
  213.         lcall    ReplyMsg        ; tell WB to unload us
  214.  
  215. noworkbench:    moveq    #-9,d0            ; the system filters out -1
  216.         rts                ; might return to cleanup
  217.  
  218.  
  219.         mc68881        ; Aztec; activate FPU instruction opcodes
  220.  
  221. resetfpu:    clr.l    -(sp)            ; call this in supervisor mode
  222.         frestore (sp)+            ; reset the FPU
  223.         rte                ; return to user mode
  224.  
  225.  
  226. * Here's our magic routine to set up a4 for accessing the copied globals.
  227. * CALL ONLY FROM WITHIN THE SAME PROCESS.
  228.  
  229. _geta4:        move.l    AbsExecBase,a4
  230.         move.l    ThisTask(a4),a4
  231.         move.l    pr_ReturnAddr(a4),a4    ; ptr to FAKE stack size
  232.         move.l    4(a4),a4        ; stored ptr to copied globals
  233.         lea    32766(a4),a4        ; add the offset
  234.         rts
  235.  
  236. dosname:    dc.b    'dos.library',0        ; for OldOpenLibrary
  237.  
  238.         dseg                ; Aztec
  239. ; Assembler bug:  If you declare __H1_org public within the code segment,
  240. ; then the assembler refers to it with small data even if you have told
  241. ; it to use large data.  Hence the above dseg is necessary.  This does not seem
  242. ; to happen with ordinary symbols, just the __Hx_xxx ones.
  243.         public    __H1_org,__H1_end,__H2_org,__H2_end    ; Aztec
  244.  
  245.     ifd    SHIT
  246. __main:        rts
  247.     dseg
  248. __savsp:    ds.l    1
  249. _SysBase:    ds.l    1
  250. _DOSBase:    ds.l    1
  251.     endc
  252.